@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

echo Update Started for CostumeCustomizer Version 2.5.1 > "%~dp0\update.log"

SET FAILED=0

FOR /L %%i in (1,1,480) DO (
  if %%i LSS 10 (
    SET PADFOLDER=0%%i
  ) else (
    SET PADFOLDER=%%i
  )

  if "%i%" == "" echo Checking for "%~dp0!PADFOLDER!"
  echo Checking for "%~dp0!PADFOLDER!" >> "%~dp0\update.log"
  IF NOT EXIST "%~dp0\!PADFOLDER!" (
    if "%i%" == "" echo Deploying template to "%~dp0!PADFOLDER!"
    echo Deploying template to "%~dp0!PADFOLDER!" >> "%~dp0\update.log"
    robocopy /E /NP "%~dp0\DISABLED template" "%~dp0\!PADFOLDER!" >> "%~dp0\update.log" 2>&1
    IF !ERRORLEVEL! GTR 7 (
      SET FAILED=1
      echo Failed to deploy template to !PADFOLDER! 1>&2
      echo ERROR: Failed to deploy template to !PADFOLDER! >> "%~dp0\update.log"
    )
  )
)

"%~dp0\CCModPackUpdater.exe" >> "%~dp0\update.log"
IF %ERRORLEVEL% NEQ 0 (
  SET FAILED=1
  if "%i%" == "" type "%~dp0\update.log"
  echo WARNING: Some Mod Packs failed to update, see %~dp0\update.log for more information. 1>&2
)

if "%1"=="" (
  if "%FAILED%" == "1" (
    echo Errors occured during update. Please review above.
  )
  PAUSE
)
exit %FAILED%